85 lines
2.9 KiB
Bash
85 lines
2.9 KiB
Bash
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
|
|
# Patched package maintainer: Saren Arterius <saren@wtako.net>
|
|
# Contributor: Ionut Biru <ibiru@archlinux.org>
|
|
# Contributor: Flamelab <panosfilip@gmail.com
|
|
|
|
pkgname=gnome-shell-performance
|
|
pkgver=3.34.0+148+g506b75fc7
|
|
pkgrel=1
|
|
pkgdesc="Next generation desktop shell | Attempt to improve the performance by non-upstreamed patches"
|
|
url="https://wiki.gnome.org/Projects/GnomeShell"
|
|
arch=(x86_64)
|
|
license=(GPL2)
|
|
depends=(accountsservice gcr 'gjs>=2:1.58' gnome-bluetooth upower gnome-session gnome-settings-daemon
|
|
gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libcroco libgdm libsecret
|
|
mutter-performance nm-connection-editor unzip gstreamer libibus gnome-autoar)
|
|
makedepends=(gtk-doc gnome-control-center 'evolution-data-server>=3.34' gobject-introspection git meson
|
|
sassc asciidoc)
|
|
optdepends=('gnome-control-center: System settings'
|
|
'evolution-data-server: Evolution calendar integration')
|
|
groups=(gnome)
|
|
provides=(gnome-shell gnome-shell=$pkgver)
|
|
conflicts=(gnome-shell)
|
|
install="$pkgname.install"
|
|
_commit=506b75fc7f3a1beeee6141ccb8edb6731c45cc6a # master
|
|
source=("$pkgname::git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
|
|
"git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
|
|
sha256sums=('SKIP'
|
|
'SKIP')
|
|
|
|
pkgver() {
|
|
cd $pkgname
|
|
git describe --tags | sed 's/-/+/g'
|
|
}
|
|
|
|
prepare() {
|
|
cd $pkgname
|
|
|
|
### Adding and fetching remotes providing the selected merge-requests
|
|
|
|
git remote add verde https://gitlab.gnome.org/verdre/gnome-shell.git || true
|
|
git fetch verde
|
|
|
|
|
|
### Merge Requests
|
|
|
|
# Merge Request Prototype
|
|
# Title:
|
|
# URL:
|
|
# Type:
|
|
# Status:
|
|
# Comment:
|
|
# git cherry-pick -n first_commit^..last_commit
|
|
#
|
|
# Possible Status:
|
|
# 1. Needs rebase: Conflicts with master branch.
|
|
# 2. Needs review: Mutter maintainers needs to review the new/updated MR and provide feedback.
|
|
# 3. Needs changes: MR needs to be adjusted based on maintainers feedback.
|
|
# 4. Merged: MR approved and it changes commited to master.
|
|
#
|
|
# Generally, a MR status oscillate between 2 and 3 and then becomes 4.
|
|
#
|
|
# Possible Type:
|
|
# 1. Improvement: Makes an already existing feature behave better, more efficiently/reliably.
|
|
# 2. Feature: Adds a new functionality.
|
|
# 3. Fix: Regression/bug fix only available in master (not backported).
|
|
# 4. Cleanup: Code styling improvement, function deprecation, rearrangement...
|
|
|
|
# Empty, because all patches are merged to master as of now
|
|
|
|
git submodule init
|
|
git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
|
|
git submodule update
|
|
}
|
|
|
|
build() {
|
|
arch-meson $pkgname build -D gtk_doc=true
|
|
ninja -C build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="$pkgdir" meson install -C build
|
|
|
|
# https://bugs.archlinux.org/task/37412
|
|
mkdir "$pkgdir/usr/share/gnome-shell/modes"
|
|
}
|